#18 – Montagem de DAX e KPIs

Definição de KPIs

Para os indicadores ou medidas desenvolvidas para o projeto, foi criado uma tabela específica para armazenamento e melhor gerenciamento dessas medidas.

Essas medidas seriam desde as mais simples, como soma acumulada das visualizações da Twitch até a categorização de jogos emergentes.

O ideal é montar essas medidas mesmo para as mais simples isso por conta dos possíveis filtros a serem desenvolvidos no dashboard, ou até mesmo filtros das páginas podem interferir nos dados.

Mesmo tendo a relação definida nas tabelas, as informações de Coleção, Empresa, Gênero, precisam de “filtros” / consultas definidas para atender o que é para ser apresentado no dashboard.

Um exemplo seria a soma acumulada (soma de visualizações de todo o período). Essa fórmula em DAX (Data Analysis Expressions) garante que a soma será entre as datas de todo o período disponível, independentemente caso um filtro de data for aplicado.

Twitch Cumulative Views = 
CALCULATE(
    SUM('Twitch Views'[Count_views]),
    FILTER(
        ALL(
        'Twitch Views'[Date_GET_Games]
        ),
        'Twitch Views'[Date_GET_Games] <= MAX('Twitch Views'[Date_GET_Games])
    )
)

Além disso, para um determinado ID, é preciso puxar todas as informações relacionada à esse ID, principalmente quando há mais de uma informação relacionada. Portanto, foi criado também uma medida em DAX para buscar essa informação concatenada (unida).

Game Genre = 
VAR jogoSelecionado = SELECTEDVALUE('IGDB Game Database'[ID_IGDB])
RETURN
CALCULATE(
    CONCATENATEX(
        VALUES('Dim Genre'[name]),
        'Dim Genre'[name],
        ", "
    ),
    'Rel Genre'[ID_IGDB] = jogoSelecionado
)

KPIs (Indicadores de Performance):

Já para os mais complexos, como o crescimento de visualizações (Views Growth) no qual compara o mês anterior com o mês atual.

IGDB Views Growth = 

VAR MesAtual = MONTH(TODAY())
VAR MesAnterior = MesAtual - 1
VAR ViewsMesAtual =
    CALCULATE([IGDB Total Views], 'Rolling Calendar'[Month] = MesAtual)
VAR ViewsMesAnterior =
    CALCULATE([IGDB Total Views], 'Rolling Calendar'[Month] = MesAnterior)
RETURN
DIVIDE(ViewsMesAtual - ViewsMesAnterior, ViewsMesAnterior)

Além disso também foi desenvolvido o KPI da quantidade de visualizações por categorias (empresa, franquia, gênero e plataforma).

IGDB Total Views Company = 
CALCULATE(
    SUM('Twitch Views'[Count_views]),
    TREATAS(
        SELECTCOLUMNS(
            FILTER(
                'Rel Company',
                RELATED('Base Company 2'[developer]) = TRUE() &&
                RELATED('Base Company 2'[company]) IN VALUES('Dim Company'[company_id])
            ),
            "ID_IGDB", 'Rel Company'[ID_IGDB]
        ),
        'Twitch IGDB ID'[ID_IGDB]
    )
)

Esses são alguns exemplos de indicadores desenvolvidos, conforme mostrado há vários outros similares que foram utilizados para o projeto.

No próximo post irei detalhar sobre as páginas do dashboard desenvolvidas, utilizando esses indicadores e métricas.

Nos vemos no próximo post!